Haskell - コードの整理とプロジェクトのビルド - Haskellのコードをモジュールにまとめる - 画象のグリッチングモジュール

開発環境

入門Haskellプログラミング (Will Kurt(著)、株式会社クイープ(監修、翻訳)、翔泳社)の UNIT6(コードの整理とプロジェクトのビルド)、LESSON 34(Haskellのコードをモジュールにまとめる)、34.4(練習問題)、Q34-2の解答を求めてみる。

コード

Main.hs

module Main where
import System.Environment ( getArgs )
import qualified Data.ByteString.Char8 as BC
import Control.Monad ( foldM )
import Glitch (randomReplaceByte, randomSortSection)
main :: IO ()
main = do
    args <- getArgs
    let fileName = head args
    imageFile <- BC.readFile fileName
    glitched <- foldM (\bytes func -> func bytes) imageFile
                      [randomReplaceByte,
                      randomSortSection,
                      randomReplaceByte,
                      randomSortSection,
                      randomReplaceByte]
    let glitchedFileName = mconcat ["glitched_",fileName]
    BC.writeFile glitchedFileName glitched
    print "all done"

コード

Glitch.hs

module Glitch(randomReplaceByte,randomSortSection) where

import Data.ByteString.Char8 qualified as BC
import System.Random ( randomRIO )

intToChar :: Int -> Char
intToChar int = toEnum safeInt
  where
    safeInt = int `mod` 256

intToBC :: Int -> BC.ByteString
intToBC int = BC.pack [intToChar int]

replaceByte :: Int -> Int -> BC.ByteString -> BC.ByteString
replaceByte loc charVal bytes = mconcat [before, newChar, after]
  where
    (before, rest) = BC.splitAt loc bytes
    after = BC.drop 1 rest
    newChar = intToBC charVal

randomReplaceByte :: BC.ByteString -> IO BC.ByteString
randomReplaceByte bytes = do
  let bytesLength = BC.length bytes
  location <- randomRIO (1, bytesLength)
  charVal <- randomRIO (0, 255)
  return (replaceByte location charVal bytes)

sortSection :: Int -> Int -> BC.ByteString -> BC.ByteString
sortSection start size bytes = mconcat [before,changed,after]
  where (before,rest) = BC.splitAt start bytes
        (target,after) = BC.splitAt size rest
        changed = BC.reverse (BC.sort target)

randomSortSection :: BC.ByteString -> IO BC.ByteString
randomSortSection bytes = do
  let sectionSize = 25
  let bytesLength = BC.length bytes
  start <- randomRIO (0, bytesLength - sectionSize)
  return (sortSection start sectionSize bytes)

入出力結果(Terminal, Zsh)

% ghc Main.hs 
Loaded package environment from /Users/.../.ghc/aarch64-darwin-9.4.8/environments/default
[1 of 3] Compiling Glitch           ( Glitch.hs, Glitch.o )
[2 of 3] Compiling Main             ( Main.hs, Main.o )
[3 of 3] Linking Main
ld: warning: ignoring duplicate libraries: '-lm'
% ./Main H._P._Lovecraft,_June_1934.jpg 
"all done"
% open glitched_H._P._Lovecraft,_June_1934.jpg
%